; PAE Access Request
; Modified for ACOS on 4/16/87

 public chk.vote

 on nocar goto no.car
 goto start

chk.vote
 f$="h:nu":gosub votes:goto link.main

no.car
 link "a:main.seg","off"

link.main
 link "a:main.seg","fromsys"

center
 b=(edit(3)/2)-(len(i$)/2):if b<1 b=1
 for a=1 to b:i$=" "+i$:next:return

show.file
 setint(1):print \s$\:open #1,f$:if mark(1) close #1:return
showfl2
 copy (20) #1
 if (eof(1) or key(1)) setint(""):close #1:return
 if not flag(35) goto showfl2
 print "Press [RETURN] ";:get i$:if i$=chr$(13) print " ";
 print chr$(8,16);chr$(32,16);chr$(8,16);
 if i$=" " setint(""):close #1:return
 setint(1):goto showfl2

start
 i$="%> PAE ProDOS Access Request <%":gosub center:print sc$\i$
 f$="h:ae":gosub votes
 f$="b:ae.request":gosub show.file
 input @0 \"Do you wish to apply? (Y/N) :" i$:if i$<>"Y" link "a:main.seg","fromsys"

 print \"Enter message now - 4k max"\".s = save|.h = help|'done' to edit msg."
 edit(0):edit(1):if not edit(2) print \"%> Aborted <%":link "a:main.seg","fromsys"

 print \"Saving...";
 open #1,"h:ae.data":input #1,x,z
 z=z+1:if z>999 z=1
 mark(1)=0:print #1,x,z:close
 f$="h:ae"+str$(z)+".user":create f$
 open #1,f$:print #1,un:close
 f$="h:ae"+str$(z)+".1":create f$:open #1,f$
 print #1,'2
Name %>'a1$' 'a2$'
Date %>'date$' 'time$'
Baud %>'ba$'
From %>'a3$\
 copy #8,#1:print #1,\'[1) Yes, give him PAE access.
[2) No, don'chr$(39)'t give him PAE.':close
 f$="h:ae"+str$(z):kill f$
 print chr$(8,6)"ed - You will be notified of the results in mail."
 goto link.main

; Subroutine for looking at user's vote results

votes
 print \"Checking votes...";
 open #1,f$+".data":input #1,a,b:close
 if a>b print "no votes found.":return
votes1
 open #1,f$+str$(a)+".user"
 input #1,x:close
 if x=un goto votes2
 a=a+1:if a<=b goto votes1
 print "your request was not found.":return
votes2
 open #1,f$+str$(a)
 mark(1)=(un/512)*64:x=mark(1):fill ram2,64,0
 read #1,ram2,64:z=flag:flag=ram2:a=flag(un)
 flag(un)=1:flag=z:mark(1)=x:write #1,ram2,64
 x=1:z=byte:byte=ram2
 position #1,32,x+7
 fill ram2,32,0:read #1,ram2,32
 b=byte(0)+byte(1)*256
 print "found."\
 if b=0 print "Nobody has voted on you yet!":goto vote5
 print "Total votes so far: "b
 y=byte(2)+byte(3)*256
 print "Yes: "(y*100)/b"% ("y")    ";
 y=byte(4)+byte(5)*256
 print "No: "(y*100)/b"% ("y")"
vote5
 close:byte=z:return