; PAE ProDOS v4.5b
; Configuration Program

 on nocar goto link.term
 goto start

link.term
 clear:recall "l:variables":kill "l:variables"
 link lm$,"term1"

load
 a$="4.5":a=250:b=0:c=1:d=2:e=5:f=1:g=0:h=1:i=100:j=50:k=10:l=255:m=128:n=1
 o=10:return

start
 print '
PAE ProDOS v4.5b Configuration Program'\chr$(45,37)
 print '
[1] Reconfigure data file
[2] Label drives
[3] Enter/change filetypes'
 input @0 \"Which? "i$:if i$="2" goto label
 if i$="3" goto filetypes
 if i$<>"1" clear:recall "l:variables":kill "l:variables":link lm$,"fromsys"

; Configure data

 open #1,bd$+"pae.data":a=mark(1)
 if a close:gosub load:goto j1
 input #1,a$\a\b\c\d\e\f\g\h\i\j\k\l\m\n\o:close
 if a$<>"4.5" kill bd$+"pae.data":gosub load
j1
 print\"01] PAE ProDOS Data File Version..................................."a$
 print "02] New User Default Points........................................"a
 print "03] SysOp Pager Toggle (0=off, 1=on)..............................."b
 print "04] Default # of Blocks U/L for a Point Added......................"c
 print "05] Default # of Blocks D/L for a Point Subtracted................."d
 print "06] Maximum # of Batched Files Allowed in Ymodem D/L..............."e
 print "07] User Kill File Ability (0=off, 1=on)..........................."f
 print "08] Free Blocks Display (0=off, 1=on).............................."g
 print "09] Store a Userlog on Disk (0=no, 1=yes).........................."h
 print "10] Number of Entries in Logs......................................"i
 print "11] # of Points to Give Uploader When His File is D/L.............."j
 print "12] Number of Top Uploader Entries................................."k
 print "13] RESERVED......................................................."l
 print "14] Length of USERS file..........................................."m
 print "15] Time Left to Download (0=off, 1=on)............................"n
 print "16] Maximum Files Allowed on ANY Drive............................."o

j2
 input \@1"Change which stat? (2-16,L,Q): "i$:if i$="L" goto j1
 if i$="Q" goto end
 bb=val(i$):if (bb<2) or (bb>16) or (bb=13) goto j2
 input @2"New value: "gh
 if bb=2 a=gh
 if bb=3 b=gh
 if bb=4 c=gh
 if bb=5 d=gh
 if bb=6 e=gh
 if bb=7 f=gh
 if bb=8 g=gh
 if bb=9 h=gh
 if bb=10 i=gh
 if bb=11 j=gh
 if bb=12 k=gh
 if bb=13 l=gh
 if bb=14 m=gh
 if bb=15 n=gh
 if bb=16 o=gh
 goto j1

end
 print \"Saving data...";
 kill bd$+"pae.data":create bd$+"pae.data"
 open #1,bd$+"pae.data":print #1,a$\a\b\c\d\e\f\g\h\i\j\k\l\m\n\o:close
 print "done."
 clear:recall "l:variables":kill "l:variables"
 link lm$,"fromsys"

filetypes
 print'
The following will allow you to change PAE ProDOS filetypes.  Enter the DECIMAL
filetype value and then the text used to represent it (ie. BIN, BAS, etc).'
 input @2\"Change filetype #"i$:if i$="Q" goto start
 a=val(i$):if a>255 goto start
 input @2\"Enter three letters for type: "i$
 if len(i$)<>3 goto start
 open #1,bd$+"pae.filetypes":position #1,4,a:input #1,x$
 if x$=i$ close:print \"No change":goto start
 if len(x$)<>3 goto file1
 print \"Current filetype: "x$
 input @0 \"Change it? "x$:if x$<>"Y" close:goto start
file1
 position #1,4,a:print #1,i$:close
 print \"Filetype changed":goto start

label
 input @2\"Label what drive? "i$:if not i$ goto start
 if right$(i$,1)=":" i$=left$(i$,(len(i$)-1))
 f$=bd$+"dat"+i$
 input @3\"Enter drive heading: "i$
 input @1"Enter flag level needed to access: "gh
 input @1"Enter drive manager's user number: "gf
 input @1"Maximum files allowed on the drive: "ww
 print'
Drive status: [0] Read/Write
              [1] Read Only
              [2] Write Only
              [3] Free Downloading (read only)'
 input @1 \"Select (0-3): "l1
 kill f$:create f$
 open #1,f$:print #1,i$\gh\gf\l1\ww:close
 print \"Drive has been labeled."
 input @0"Do another? (y/n): "i$:if i$="Y" goto label
 goto start