; User Robbing
; Modified for ACOS on 04/29/87

 on nocar goto no.car
 goto start

no.car
 poke 34,4:if info(0)=0 poke 34,0
 link "a:main.seg","off"

center
 b=(edit(3)/2)-(len(a$)/2):if b<1 b=1
 a$=chr$(32,b)+a$:return

show.file
 setint(1):print \s$\:open #1,f$:if mark(1) close #1:return
showfl2
 copy (20) #1
 if (eof(1) or key(1)) setint(""):close #1:return
 if not flag(35) goto showfl2
 print "Press [RETURN] ";:get i$:if i$=chr$(13) print " ";
 print chr$(8,16);chr$(32,16);chr$(8,16);
 if i$=" " setint(""):close #1:return
 setint(1):goto showfl2

link.main
 poke 34,4:if info(0)=0 poke 34,0
 link "a:games.seg","fromsys"

start
 if info(0) poke 34,4
 print sc$:print #3 @1,5 "User: "
 print #3 @30,5 "O1: ????  O2: ???? C1: ???? C2: ????   [ 100]"
 print #3 @1,6 chr$(45,79):poke 34,6
 a$="%> User Robbing <%":gosub center:print a$
start1
 print #3 \"ROBBED = List of users robbed on this call"
 gosub to.who:if (d=0) and (i$="Q") goto link.main
 if (d=0) or (d=un) goto start1
 a=d:print \"Checking that record...";
 f$="f:u."+str$(a):open #1,f$:x=mark(1)
 if x close:print "deleted.":goto start1
 print "verified.":position #1,5,2:input #1,r
 position #1,5,1:input #1,s2:close
 print \"User #"a" is: "d1$\
 create "l:robbed":open #1,"l:robbed":position #1,2,a:input #1,i$:close
 if i$="Y" print "You've already attacked "d1$" on this call.":goto start1
 print a4$" vs. "d1$\\"Reading reserve credits...";
 vb=a:f$="f:u."+str$(un):open #1,f$:position #1,5,2:input #1,f
 position #1,5,1:input #1,s1:close
 print "done."
 if (f<10) and (not flag(4)) and (info(0)) goto out
 i$=str$(r):gosub comma
 print d1$" has "i$" credits.":i$=str$(f):gosub comma
 print "You have "i$" credits."\
 if r<1 print d1$" has no credits!":goto start1
 rr=50:s1=s1/10:s2=s2/10
 if s1>s2 rr=50+s1:if rr>80 rr=80 
 if s2>s1 rr=50-s2:if rr<20 rr=20
 if s1>s2 print a4$" is favored to win by "rr"%."
 if s2>s1 print d1$" is favored to win by "100-rr"%."
 if rr=50 print "There are no favorites in this match!"
 print \"Do you wish to continue? ";:gosub get.key
 if i$<>"Y" print "No":goto start1
 print "Yes":zx=0:if (not flag(4)) and (info(0)) goto no.cheat
 print "Enable cheating? ";:gosub get.key
 if i$="Y" print "Yes":zx=1
 if i$<>"Y" print "No"
no.cheat
 if (flag(4)=0) and (info(0)) open #1,"l:robbed":position #1,2,a:print #1,"Y":close
 i$=left$(d1$+chr$(32,23),23):print #3 @7,5 i$
 i$=right$("   "+str$(f),4):print #3 @34,5 i$
 i$=right$("   "+str$(r),4):print #3 @44,5 i$
 f1=f:r1=r:a1=f:a2=r
 zz=(len(d1$)+16)+24
 print sc$\chr$(32,6)"Command"chr$(32,7)"|"chr$(32,6)"Status"
 if not flag(32) print chr$(45,zz):else print p$;chr$(211,zz);n$
 t=100
start2
 on nocar goto quit
 print "Steal/Change/Quit:";:gosub get.key
 print i$" | ";
 if i$="C" goto change
 if i$="Q" print:goto quit
 if i$="S" print "Steal!":goto steal
 print:goto start2

change
 i$=str$(t):gosub comma
 print \"Change amount from "i$;:input @1 " to: " a:if a<1 goto change
 t=a:i$=right$("   "+str$(t),4)
 x=peek(36)+1:y=peek(37)+1:print #3 @70,5 i$
 print #3 @x,y "";
 goto start2

quit
 if not flag(32) print chr$(45,zz):else print p$;chr$(204,zz);n$
 if r1<a2 x1=1:else x1=0
 if f1>9500 f1=9500
 if r1>9500 r1=9500
 print \"Saving results -":i$=str$(f1):gosub comma
 print "You have "i$" credits.":i$=str$(r1):gosub comma
 print d1$" has "i$" credits."
 f$="f:u."+str$(un):open #1,f$:position #1,5,2:print #1,f1:close
 f$="f:u."+str$(vb):open #1,f$:position #1,5,2:print #1,r1:close
 i$=str$(a1-f1):gosub comma
 if x1=0 print "You lost a total of "i$" credits.":goto quit1
 i$=str$(a2-r1):gosub comma:print d1$" lost "i$" credits."
 if an goto quit0
 b$=i$:edit(0):ready "e:gmail"
 if info(6)<29 print \"Mail bit-map full!":goto quit0
 gosub date1:print #msg(vb),un
 print #6,'Letter From -%>User Robbing
Date Mailed -%>'i$\
 print #6,a4$;:if nb$ print #6," ["nb$"]";
 print #6," (#"un") stole a total of "b$" credits from you."
 copy #8,#6:print #msg(vb),chr$(4);chr$(0);:msg(vb)=msg(vb)+1:update
quit0
 open #1,f$:position #1,5,16:input #1,z:z=z+(a2-r1):if z>9500 z=9500
 position #1,5,16:print #1,z:position #1,5,15:input #1,z
 close:if z goto quit1
 print \d1$" has no insurance!"
quit1
 on nocar goto no.car
 if an<1 gosub rob.log
 print \"Results saved.":goto start1

steal
 b=random(3)+3
 for a=1 to b:x2=0
 print chr$(32,20)"| ";
 if (f<1) or (r<1) print "Out of credits!":a=b:next:goto quit
 if (t>r) or (f<t) print "Change amount!":a=b:next:goto start2
 i$=rnd$:x1=random(100):x=peek(36)+1:y=peek(37)+1
 if peek(-16287)>127 x1=100:print #3 @76,5 "[L]"
 if zx or (peek(-16286)>127) x1=1:print #3 @76,5 "[W]"
 if (peek(-16287)>127) and (peek(-16286)>127) x1=100:x2=1:print #3 @76,5 "[B]"
 print #3 @x,y "";
 if x1<rr goto win
 i$=rnd$:x=random(999):if x2 x=1000
 if x>950 print "Backstabbed!  ";
 if x>950 f=f-(t*3):r1=r1+(t*3):f1=f1-(t*3)
 if x<951 print "You lose... ";:f=f-t:r1=r1+t:f1=f1-t
 i$=str$(f):gosub comma:print i$" left"
win
 if x1<rr r=r-t:f1=f1+t:r1=r1-t:i$=str$(r):gosub comma
 if x1<rr print d1$" has "i$" left"
 x=peek(36)+1:y=peek(37)+1
 print #3 @76,5 "   "
 print #3 @53,5 right$("   "+str$(f),4)
 print #3 @62,5 right$("   "+str$(r),4)
 print #3 @x,y "";
 if (f<1) or (r<1) a=b:next:goto quit
 next:goto start2
 
out
 print \"You don't even have 10 credits!"\"[hit a key]";
 gosub get.key:goto link.main

rob.log
 if (x1=0) and (a1-f1=0) return
 f$="b:robbing.log":create f$
 open #1,f$:position #1,80,0:input #1,a:a=a+1:if a=100 a=1
 position #1,80,0:print #1,a:position #1,80,a
 i$=a4$+chr$(32,24):x$=d1$+chr$(32,24)
 z$=":":if z z$="."
 print #1,"["date$"]"z$" "left$(i$,24);
 if x1=0 print #1," lost";:else print #1,"  won";
 if x1=0 a$=right$("   "+str$(a1-f1),4):else a$=right$("   "+str$(a2-r1),4)
 print #1," "a$" ";
 if x1=0 print #1,"   to ";:else print #1," from "; 
 print #1,left$(x$,24)
 close:return
 
date1
 q=val(left$(date$,2)):q1=val(mid$(date$,4,2)):q2=val(right$(date$,2))
 m$="000031059090120151181212243273304334":if q>1 q3=val(mid$(m$,q*3-2,3))
 q1=q1+q3:m$="46012356":q1=q1+val(mid$(m$,8-(94-q2),1)):q1=q1 mod 7
 m$="BobMonTueWedThuFriSat":if q1>1 td$=mid$(m$,q1*3-2,3):else td$="Sun"
 ml$="085534469788":q3=0:for q4=1 to q-1:q3=q3+val(mid$(ml$,q4,1):next
 mt$="FebruaryMarchAprilMayJuneJulyAugustSeptemberOctoberNovemberDecember"
 if q>1 m$=mid$(mt$,q3+1,val(mid$(ml$,q4+1,1))):else m$="January"
 min$=mid$(time$,4,2):if len(time$)>8 tm$=time$:goto date2
 if val(left$(time$,2))<12 tm$=left$(time$,2)+":"+min$+"AM":goto date2
 q4=val(left$(time$,2)):tm$=str$(12-(24-q4))+":"+min$+"PM"
date2
 i$=td$+", "+m$+" "+mid$(date$,4,2)+"  "+tm$
 return

get.key
 ww=0:wx=0
get.key1
 gf=clock(2)
 if (gf<>0) and (clock(1)>gf) print \\"[ Time Limit Exceeded ]":pop:goto no.car
 gf=peek(-16384):if (gf=129) or (gf=150) get i$:print chr$(8);:return
 gf=key(0):if (gf>96) and (gf<123) gf=gf-32
 if (gf>31) or (gf=13) or (gf=14) i$=chr$(gf):return
 ww=ww+1:if flag(33)=0 goto get.key2
 wx=wx+1:if wx>16 wx=1
 print mid$("!/-\!/-\!\-/!\-/",wx,1);chr$(8);
get.key2
 if ww=2000 print chr$(7,2);
 if ww=4000 pop:goto no.car
 if (not info(0)) and (not info(5)) and (eu<>1) pop:goto no.car
 goto get.key1

; Send to user

to.who
 print \"From who? [1-"nu;:input @2 ",Q]: "i$
 if (i$="") or (i$="Q") d=0:return
 if i$="ROBBED" gosub rob.list:goto to.who
 if left$(i$,1)="#" i$=mid$(i$,2):goto snd.num
 if val(left$(i$,1)) goto snd.num
 d$=i$:if (d$="SYSOP") or (d$=sys$) d=1:return
 gosub lower.case:d$=ab$
 kill "l:matches":create "l:matches"
 open #2,"l:matches"
 open #1,"b:users":d=1:gf=0
 
snd.user
 position #1,64,d
 input #1,d1$,i$:if i$<>"." d1$=d1$+" "+i$
 if d1$=d$ close #1:close #2:return
 if instr(d$,d1$) position #2,30,gf:print #2,d,d1$:gf=gf+1
 if d<nu d=d+1:goto snd.user
 close #1:if gf goto snd.usr3
 close #2:d=0
 print \d$" is not a user.":return
snd.usr2
 print \"That user does not exist."
 d=0:return
snd.usr3
 print \"That user does not exist.  Matching users:"\
 for c=0 to gf-1:position #2,30,c:input #2,d,d1$
 print d1$" [#"d"]":next:close #2
 input @1\"Select user # (0=quit): "i$
 if i$="0" d=0:return
 
snd.num
 d=val(i$)
 if (d<1) or (d>nu) goto snd.usr2
 open #1,"b:users"
 position #1,64,d:input #1,d1$,i$:close #1
 if d1$="" goto snd.usr2
 if i$<>"." d1$=d1$+" "+i$
 d0$="Rob from "+d1$+"? "
snd.num2
 print \d0$;
 gosub get.key:if i$<>chr$(14) an=0:goto snd.num1
 print chr$(8,len(d0$));chr$(32,len(d0$));chr$(8,len(d0$));
 print "Do it anonymously? ";
 gosub get.key:if i$<>"Y" print "No":goto snd.num2
 an=1
snd.num1
 if i$<>"Y" d=0:print "No":else print "Yes"
 return

lower.case
 if len(i$)=1 ab$=i$:return
 ab$=left$(i$,1):for wy=2 to len(i$):wx=asc(mid$(i$,wy,1))
 if wx=32 ab$=ab$+" "+mid$(i$,wy+1,1):wy=wy+1:next:return
 if (wx<65) or (wx>96) ab$=ab$+chr$(wx):next:return
 ab$=ab$+chr$(wx+32):next:return

rob.list
 open #1,"l:robbed":a=mark(1):if a close:print \"No users robbed.":return
 print \"Users robbed by you on this call:"\
 open #2,"b:users":for a=1 to nu:position #1,2,a:input #1,i$
 if i$<>"Y" goto rlist1
 position #2,64,a:input #2,d4$,d2$:if d2$<>"." d4$=d4$+" "+d2$
 print d4$
rlist1
 next:print \"[ End of list ]":close #1:close #2:return

comma
 if len(i$)<4 return
 if len(i$)<5 gf=1:else gf=2
 i$=left$(i$,gf)+","+right$(i$,3):return