; ulist.seg
; modified for ACOS on 03/29/87

 public link.main
 public no.car

 on nocar goto no.car
 kill "l:variables":store "l:variables"
 goto start

no.car
 clear:recall "l:variables"
 link "a:main.seg","term1"

link.main
 clear:recall "l:variables"
 link "a:main.seg","fromsys"

center
 b=(edit(3)/2)-(len(a$)/2):if b<1 b=1
 print chr$(32,b);
 if flag(32) print chr$(15);a$;chr$(14):return
 print a$:return

start
 print sc$
 if flag(32) a$=chr$(32,15)+chr$(14,2):gosub center
 if flag(32) a$=" "+chr$(14)+" Userlisting "+chr$(15)+" ":gosub center
 if flag(32) a$=chr$(32,15)+chr$(14,2):gosub center
 if not flag(32) a$="%> Userlisting <%":gosub center
 setint(1):print '
Choose:

[1] Full Userlist
[2] Letter Search
[3] State Search
[4] User Ratings
[5] Loserlist':setint("")
 print \"Select: ";:gosub get.key:a=val(i$)
 if (a<1) or (a>5) print "Quit...":goto link.main
 print a:if a=4 link "a:rating.seg"
 if a=5 link "a:loserlist.seg"
 if a=1 goto full
 if a=2 goto letter

 print \"List users in state: ??"chr$(8,2);:input @1 dd$
 x=1:t=0:yy=1:if dd$="Q" goto start

list
 if not info(5) goto list0
 print \"Show passwords? ";:gosub get.key
 if i$<>"N" print "Yes":an=1:else print "No":an=0
list0
 a1=0:a2=0:a3=0:a4=0:a5=0:a6=0
; Totals: Empty accounts, users, validated, unvals, males, females
 print'
###|_Username and Location___________|_Last On|S|Lv|_Phone #____';
 if info(5) and an print "|_Password";
 print:open #1,"b:users"
list1
 position #1,64,x:input #1,a$,b$\d3$
 move ram,34 to ram2:on nocar clear
 if a$="" a1=a1+1:goto list2
 a2=a2+1:if b$<>"." a$=a$+" "+b$
 if (yy=1) and (right$(d3$,2)<>dd$) goto list2
 if (yy=2) and (not instr(dd$,a$)) goto list2
 a$=a$+" from "+d3$:position #1,64,x,30
 read #1,ram,34:t=t+1:setint(1)
 print right$("  "+str$(x),3)"|";
 print left$(a$+chr$(32,33),33)"|";
 print when$"|";
 if nibble(1)=2 print "F";:a6=a6+1
 if nibble(1)=1 print "M";:a5=a5+1
 if (nibble(1)<>1) and (nibble(1)<>2) print "?";
 gh=0
 if flag(1) gh=1:a3=a3+1:else a4=a4+1
 if flag(3) gh=2
 if flag(4) gh=3
 if flag(34) gh=99
 print "|"right$(" "+str$(gh),2)"|";
 d1$=mid$(ph$,4,1)
 if d1$=" " or info(5) print ph$;:else print chr$(32,12);
 if info(5) and an print "|";:if (x<>un) print pa$;
 print
list2
 setint(""):move ram2,34 to ram:on nocar goto no.car
 if (not key(1)) and (x<nu) x=x+1:goto list1
 close:if x<>nu print "%> Aborted <%":goto hit.key
 if yy=1 print \"[ There are "t" users in "i$" state ]"
 if yy goto hit.key
 print '
[ Totals ]

 Empty user accounts: 'a1'
Filled user accounts: 'a2'
     Validated users: 'a3'
   Unvalidated users: 'a4'
               Males: 'a5'
             Females: 'a6

hit.key
 print \"[hit a key]";:gosub get.key:goto start

letter
 input @3 \"Search for letters: "dd$:if dd$="" goto start
 x=1:yy=2:goto list

full
 input @2 \"Start at user #"x:if (x<1) or (x>nu) goto start
 yy=0:goto list

get.key
 ww=0:wx=0
get.key1
 gf=clock(2)
 if (gf<>0) and (clock(1)>gf) print \\"[ Time Limit Exceeded ]":pop:goto no.car
 gf=peek(-16384):if (gf=129) or (gf=150) get i$:print chr$(8);:return
 gf=key(0):if (gf>96) and (gf<123) gf=gf-32
 if (gf>31) or (gf=13) i$=chr$(gf):return
 ww=ww+1:if flag(33)=0 goto get.key2
 wx=wx+1:if wx>16 wx=1
 print mid$("!/-\!/-\!\-/!\-/",wx,1);chr$(8);
get.key2
 if ww=2000 print chr$(7,2);
 if ww=4000 pop:goto no.car
 if (not info(0)) and (not info(5)) and (eu<>1) pop:goto no.car
 goto get.key1