; Userpurge Util
; Written on: 6/26/87

 on nocar goto no.car

 gh=0:ab=0:bs$=chr$(8)
 print \"Delete before: XX/XX/XX"chr$(8,8);
 input @2 a$:if not a$ goto link.sys
 f$="b:deletions"
 kill f$:create f$
 open #2,f$:print #2,'
This is a list of the users who were either deleted or came up for deletion
during a routine user purge from last date logged on.  If the user was deleted,
a bracket encloses the name.

The last user purge was on 'date$' for users who had not logged on
since 'a$'.

User Name                Last On
---------------------------------'\

 input @1 "Start at user #"a
 move ram,34 to ram2:open #1,"b:users"
 for b=a to nu
 position #1,64,b:gosub rd.user
 if (not d1$) or (not d2$) gh=gh+1:gosub update:goto back
 x=val(right$(lc$,2)):y=val(right$(a$,2))
 if (x<y) or (lc$<a$) goto kill
back
 next:close #1:goto end

update
 kill "f:u."+str$(b)
 kill "f:r."+str$(b)
 kill "f:b."+str$(b)
 return

kill
 print \d1$" "d2$
 print d3$\b"-"pa$\ph$
 for x=1 to 34:print flag(x);:next
 print \lc$
 print\"Kill this user? (Y/[N]): ";:gosub get.key
 if i$="Y" goto kill.yes
 print "No":i$=left$(d1$+" "+d2$+chr$(32,25),25)
 print #2,i$" "lc$
 goto back
kill.yes
 print "Yes":i$=left$("["+d1$+" "+d2$+"]"+chr$(32,25),25)
 print #2,i$" "lc$
 d1$="":gosub wr.user:ab=ab+1
 gosub update:goto back

rd.user
 input #1,d1$,d2$\d3$
 position #1,64,b,30
 read #1,ram,34
 lc$=mid$(" "+when$,2)
 return

wr.user
 position #1,64,b
 print #1,d1$\d3$:position #1,64,b,30
 write #1,ram,34
 ready "e:mail":kill #msg(b):update
 ready "e:gmail":kill #msg(b):update
 return

link.sys
 close #2:link "a:system.seg"

no.car
 close #2:link "a:main.seg","off"

end
 print #2,\'Old empty accounts: 'gh'
Number of current empty accounts: 'gh+ab'
Number of users purged: 'ab'
Total number of users: 'nu-(gh+ab)

 print \"Old empty slots: "gh
 print "Number of current empty slots: "gh+ab
 print "Number of users purged: "ab
 print "Total # of users: "nu-(gh+ab)
 move ram2,34 to ram:goto link.sys

get.key
 ww=0:wx=0
get.key1
 if clock(2) and (((clock(2)-clock(1)) mod 60)<0) print\"[Time Limit Exceeded]":goto no.car
 gf=peek(-16384):if (gf=129) or (gf=150) get i$:print bs$;:return
 gf=key(0):if (gf>96) and (gf<123) gf=gf-32
 if gf i$=chr$(gf):print " "bs$;:return
 ww=ww+1:if not flag(33) goto get.key2
 wx=wx+1:if (wx=1) or (wx=5) or (wx=9) or (wx=13) print "!";
 if (wx=2) or (wx=6) print "/";
 if (wx=3) or (wx=7) print "-";
 if (wx=4) or (wx=8) print "\";
 if (wx=10) or (wx=14) print "\";
 if (wx=11) or (wx=15) print "-";
 if (wx=12) or (wx=16) print "/";
 if wx=16 wx=0
 print bs$;
get.key2
 if ww=2000 print chr$(7,2);
 if ww=4000 pop:goto no.car
 goto get.key1