4  REM 
** SET VARIABLES TO MEET YOUR CONFIGURATION IN LINE 5 **

 5 A$ = "/SIDER/SEGS":B$ = "/SIDER/SEGS/ACOS":C$ = "/SIDER/DATA/MOD.DATE"
 9  REM 
** REMOVE LINE 10 IF YOU DO NOT WANT AUTO-LOAD ON **

 10  POKE 0,1: POKE 1,2
 15  GOSUB 100: POKE 16384, LEN (A$)
 20  FOR A = 1 TO  LEN (A$)
 30  POKE (16385 + A - 1), ASC ( MID$ (A$,A,1))
 40  NEXT 
 50  FOR A = 1 TO 77: READ B: POKE 8191 + A,B: NEXT : CALL 8192
 55  IF  PEEK (8192) = 220 THEN 1000
 60 Y =  PEEK (8192):M =  PEEK (8193):D =  PEEK (8194)
 70 H =  PEEK (25869):MM =  PEEK (25868)
 80  PRINT : PRINT "Latest modification: "M"/"D"/"Y" "H":"MM
 95  GOTO 400
 100 D$ =  CHR$ (4)
 110  HOME : INVERSE : PRINT "\" SPC( 38)"/";
 120  NORMAL : PRINT  SPC( 10)"ACOS QuickLoader v1.0"
 130  PRINT  SPC( 13)"Written by -DC-"
 140  PRINT : PRINT "Call Shooting Star BBS/PAE..206/838-7686";
 150  INVERSE : PRINT "/" SPC( 38)"\": NORMAL 
 160  PRINT : PRINT "Reading "A$"...": RETURN 
 400  ONERR  GOTO 900
 500  PRINT D$"OPEN"C$: PRINT D$"READ"C$
 510  INPUT M1,D1,Y1,H1,M2: PRINT D$"CLOSE"
 515  POKE 216,0
 520  PRINT "           Previous: "M1"/"D1"/"Y1" "H1":"M2
 530  IF (Y1 <  > Y) OR (M1 <  > M) OR (D1 <  > D) OR (H1 <  > H) OR (M2 <  > MM) THEN 920
 540  PRINT : PRINT "Running loader in FAST mode..."
 550  PRINT D$"BLOAD"B$",TSYS,A$2000"
 555  IF ( PEEK (9796) <  > 208) OR ( PEEK (9797) <  > 23) OR ( PEEK (9798) <  > 165) THEN 3010
 560  POKE 9796,76: POKE 9797,93: POKE 9798,110
 580  CALL 8192: END 
 900  POKE 216,0
 910  PRINT D$"CLOSE"
 920  PRINT D$"OPEN"C$: PRINT D$"WRITE"C$
 930  PRINT M","D","Y","H","MM: PRINT D$"CLOSE"
 940  PRINT : PRINT "Running loader in NORMAL mode..."
 950  PRINT D$"-"B$: END 
 1000  PRINT  CHR$ (7); CHR$ (7): PRINT "ERROR #" PEEK (8193)" - ";: GOTO 2020
 2000  DATA   169,10,141,0,101,169,0,141,1,101,169,64,141,2,101,32,0,191,196,0,101,176,44,173,11,101,41,254,106,141,0,32,173,11,101,41,1,42, 42,42,141,1,32
 2010  DATA  173,10,101,41,224,42,42,42,42,77,1,32,141,1,32,173,10,101,41,31,141,2,32,96,141,1,32,169,220,141,0,32,96,36
 2020 A =  PEEK (8193): IF A = 39 THEN  PRINT "I/O ERROR"
 2030  IF A = 64 THEN  PRINT "INVALID PATHNAME SYNTAX"
 2040  IF A = 68 THEN  PRINT "PATH TO SUBDIRECTORY IS BAD"
 2050  IF A = 69 THEN  PRINT "VOLUME DIRECTORY NOT FOUND"
 2060  IF A = 70 THEN  PRINT "SUBDIRECTORY FILE NOT FOUND"
 2070  IF A = 74 THEN  PRINT "INCOMPATIBLE FILE FORMAT"
 2080  IF A = 75 THEN  PRINT "BAD STORAGE TYPE"
 2090  IF A = 90 THEN  PRINT "DAMAGED FREESPACE BIT MAP"
 3000  END 
 3010  PRINT  CHR$ (7); CHR$ (7): PRINT "ERROR - INCORRECT ACOS VERSION": END